/* 
baseline_NLRB_CBP.do
runs baseline estimates with NLRB data
replicates Table 4

*/

#delimit ;

log using c:\a_datprg\proj\union\geo_spill\dat_public\baseline_NLRB_CBP.log, replace;

clear;
set memory 1000m;
set more off;
program drop _all;
use d:\a_data\proj\union\geo_spill\dat_public\nlrb_cbp_dat;

desc;


* Generate State Level variables;
qui gen dum_south=0;
qui replace dum_south=1 if (sttext=="TX") | (sttext=="LA") | (sttext=="AR") | (sttext=="MS") | (sttext=="TN") | (sttext=="AL") | (sttext=="FL")
| (sttext=="GA") | (sttext=="SC") | (sttext=="NC") | (sttext=="VA");

keep if dum_south==1;
*Now generate dummy variables (sttext1-sttext11) for states;
tabulate sttext, generate(sttext);

* Location level variables;
qui gen mine_shr=(ng_emp10+ng_emp11+ng_emp12)/ng_totemp60;
qui gen steel_shr=ng_emp33/ng_totemp60;
qui gen spillover=mine_shr+steel_shr;
qui gen s_white_foreign=1-s_par_native;

qui gen metro=1;
qui replace metro=0 if (msacmsa=="9999") | ((msacmsa=="####") & (necma=="9999"));
qui gen popden=.001*pop2000/land;
qui replace pci=.001*pci;

* Estabslishment level variables;
qui gen dum_size1=0; qui replace dum_size1=1 if empcat=="01";
qui gen dum_size2=0; qui replace dum_size2=1 if empcat=="02";
qui gen dum_size3=0; qui replace dum_size3=1 if empcat=="03";

qui gen union=0; qui replace union=1 if nlrbcount>=1;

qui gen dum15_=(sic3=="15-");
qui gen dum514=(sic3=="514");
qui gen dum541=(sic3=="541");
qui gen dum701=(sic3=="701");
qui gen dum805=(sic3=="805");
qui gen dum806=(sic3=="806");

*Finally generate stcounty to use for clustering;
gen stcounty = st+county;


sum union dum_size1 dum_size2 dum_size3 dum805 dum806 s_white_foreign s_black popden spillover 
if ( (sic3=="805") | (sic3=="806"));
sum union dum_size1 dum_size2 dum_size3 dum514 dum541 dum701 dum15_ s_white_foreign s_black popden spillover
if ~( (sic3=="805") | (sic3=="806"));


save d:\a_data\temp\t, replace;

*Estimate 1 Nursing homes and hospitals;
use d:\a_data\temp\t, replace;
keep if (sic3=="805") | (sic3=="806");
logit union
dum_size2 dum_size3  dum806
s_white_foreign s_black popden sttext2-sttext11 spillover, robust cluster(stcounty);


*Estimate 2 Other Nontraded industries;
use d:\a_data\temp\t, replace;
keep if (sic3=="15-") | (sic3=="514") | (sic3=="541") | (sic3=="701");
logit union
dum_size2 dum_size3  dum514 dum541 dum701
s_white_foreign s_black popden sttext2-sttext11  spillover, robust cluster(stcounty);


*Estimate 3: Breakdown of Nontraded industries;
sort sic3;
by sic3: logit union 
dum_size2 dum_size3 s_white_foreign s_black popden sttext2-sttext11  spillover , robust cluster(stcounty);

log close;
#delimit cr